Homec4science
Diffusion COSOlver (master) Browse

cosolver/src/operator_model_mod.f90
5b66a09e0f20master

Last Change
Raw File

operator_model_mod.f90
View Options

MODULE operator_model
!
! This model contains all the operator model definitions
!
USE prec_const
USE basic
USE basic_mpi
USE fmzm
USE model
USE Coulomb
USE Coulomb_pol
USE Sugama
USE improved_sugama
USE abel
USE pitchangle
use hirshmansigmar
use dougherty
!
IMPLICIT NONE
public
! Define operator model procedure
! Electron operators
PROCEDURE(OPERATORT), POINTER :: COLLISIONTE => null()
PROCEDURE(OPERATORF),POINTER :: COLLISIONFE => null()
! Ion Operators
PROCEDURE(OPERATORT), POINTER :: COLLISIONTI => null()
PROCEDURE(OPERATORF), POINTER :: COLLISIONFI => null()
! Self Operators
PROCEDURE(OPERATORSELF), POINTER :: COLLISIONSELFE => null()
PROCEDURE(OPERATORSELF), POINTER :: COLLISIONSELFI => null()
ABSTRACT INTERFACE
SUBROUTINE OPERATORT(l,k,rCabT)
! Test operator
USE prec_const
IMPLICIT NONE
INTEGER,INTENT(in) :: l,k
! REAL(dp),DIMENSION(:,:),INTENT(inout) :: CabT
TYPE(FM),DIMENSION(:),INTENT(inout) :: rCabT
END SUBROUTINE OPERATORT
END INTERFACE
ABSTRACT INTERFACE
SUBROUTINE OPERATORF(l,k,rCabF)
! Field/back-reaction operator
USE prec_const
IMPLICIT NONE
INTEGER,INTENT(in) :: l,k
! REAL(dp),DIMENSION(:,:),INTENT(inout) :: CabF
TYPE(FM),DIMENSION(:),INTENT(inout) :: rCabF
END SUBROUTINE OPERATORF
END INTERFACE
ABSTRACT INTERFACE
SUBROUTINE OPERATORSELF(l,k,rCaa)
! Field/back-reaction operator
USE prec_const
IMPLICIT NONE
INTEGER,INTENT(in) :: l,k
! REAL(dp),DIMENSION(:,:),INTENT(inout) :: CabF
TYPE(FM),DIMENSION(:),INTENT(inout) :: rCaa
END SUBROUTINE OPERATORSELF
END INTERFACE
PUBLIC:: COLLISIONTE,COLLISIONFE,COLLISIONTI,COLLISIONFI,COLLISIONSELFE,COLLISIONSELFI,SET_OPERATOR_MODEL
CONTAINS
!_______________________________________________________________________
SUBROUTINE SET_OPERATOR_MODEL
! sets the field and back-reaction collision operator model
!
IMPLICIT NONE
!
! electrons coll.
IF(eicolls) call set_operator_ei_model
IF(eecolls) call set_operator_ee_model
! ions coll.
IF(iecolls) call set_operator_ie_model
IF(iicolls) call set_operator_ii_model
!
!
END SUBROUTINE SET_OPERATOR_MODEL
!
!_______________________________________________________________________
!
subroutine set_operator_ei_model
! set ei collision operator model
implicit none
! Test component
SELECT CASE (ETEST)
CASE(1) ! ... coulomb
IF (GKE) THEN
! COLLISIONTE => coulombTGK
IF(me .eq. 0 ) WRITE(*,*) 'ETEST ==> GK Coulomb'
ELSE
COLLISIONTE => coulombTDK
IF(me .eq. 0 ) WRITE(*,*) 'ETEST ==> DK Coulomb'
ENDIF
CASE(2) ! ... pitch angle
COLLISIONTE => LorentzDK
IF(me .eq. 0 ) WRITE(*,*) 'ETEST ==> DK Lorentz (with constant nu)'
CASE(3) ! .... Sugama collision operator
IF(GKE) THEN
COLLISIONTE => SugamaTGK
IF(me .eq. 0) WRITE(*,*) 'ETEST ==> GK Sugama'
ELSE
COLLISIONTE => SugamaTDK
IF(me .eq. 0) WRITE(*,*) 'ETEST ==> DK Sugama'
ENDIF
CASE(4) ! .... Deflection pitch-angle scattering operator
IF( GKE) THEN
COLLISIONTE => pitchTGK
IF(me .eq. 0) WRITE(*,*) 'ETEST ==> GK pitch-angle scattering (with nu = nuD(v))'
ELSE
COLLISIONTE => pitchTDK
IF(me .eq. 0) WRITE(*,*) 'ETEST ==> DK pitch-angle scattering (with nu = nuD(v))'
ENDIF
CASE(5) ! .... Improved Sugama collision operator
IF(GKE) THEN
COLLISIONTE => ImprovedSugamaTGK
IF(me .eq. 0) WRITE(*,*) 'ETEST ==> GK Improved Sugama'
ELSE
COLLISIONTE => ImprovedSugamaTDK
IF(me .eq. 0) WRITE(*,*) 'ETEST ==> DK Improved Sugama'
ENDIF
CASE(6) ! .... zeroth order Hirshman-Sigmar-Clarke operator
!
COLLISIONTE => hirshmansigmar0T
IF(me .eq. 0) WRITE(*,*) 'ETEST ==> DK (only DK) zeroth order Hirshman-Sigmar-Clarke'
CASE(0)
COLLISIONTE => BUFFOPERATORT
CASE DEFAULT
IF(me .eq. 0 ) write(*,*) 'Operator model not defined....'
END SELECT
! Field component
SELECT CASE (EBACK)
CASE(1) ! ... coulomb
IF(GKE) THEN
IF(me .eq. 0 ) WRITE(*,*) 'EBACK ==> GK Coulomb'
!! COLLISIONFE => coulombFGK
ELSE
IF(me .eq. 0 ) WRITE(*,*) 'EBACK ==> DK Coulomb'
COLLISIONFE => coulombFDK
ENDIF
CASE(3) ! .... Sugama collision operator
IF(GKE) THEN
COLLISIONFE => SugamaFGK
IF(me .eq. 0) WRITE(*,*) 'EBACK ==> GK Sugama'
ELSE
COLLISIONFE => SugamaFDK
IF(me .eq. 0) WRITE(*,*) 'EBACK ==> DK Sugama'
ENDIF
Case(5) ! .... Improved Sugama collision operator
IF(GKE) THEN
COLLISIONFE => ImprovedSugamaFGK
IF(me .eq. 0) WRITE(*,*) 'EBACK ==> GK Improved Sugama'
ELSE
COLLISIONFE => ImprovedSugamaFDK
IF(me .eq. 0) WRITE(*,*) 'EBACK ==> DK Improved Sugama'
ENDIF
CASE(6) ! .... zeroth order Hirshman-Sigmar-Clarke operator
!
COLLISIONFE => hirshmansigmar0F
IF(me .eq. 0) WRITE(*,*) 'EBACK ==> DK zeroth order Hirshman-Sigmar-Clarke'
CASE(0)
COLLISIONFE => BUFFOPERATORF
CASE DEFAULT
IF(me .eq. 0 ) write(*,*) 'Operator model not defined....'
END SELECT
end subroutine set_operator_ei_model
!
!_______________________________________________________________________
!
subroutine set_operator_ie_model
! set ie collision operator model
implicit none
! Test component
SELECT CASE (ITEST)
CASE(1) ! ... coulomb
IF (GKI) THEN
IF(me .eq. 0 ) WRITE(*,*) 'ITEST ==> GK Coulomb'
! COLLISIONTI => coulombTGK
ELSE
IF(me .eq. 0 ) WRITE(*,*) 'ITEST ==> DK Coulomb'
COLLISIONTI => coulombTDK
ENDIF
CASE(3) ! .... Sugama collision operator
IF(GKI) THEN
COLLISIONTI => SugamaTGK
IF(me .eq. 0) WRITE(*,*) 'ITEST ==> GK Sugama'
ELSE
COLLISIONTI => SugamaTDK
IF(me .eq. 0) WRITE(*,*) 'ITEST ==> DK Sugama'
ENDIF
CASE(5) ! .... Improved Sugama collision operator
IF(GKI) THEN
COLLISIONTI => ImprovedSugamaTGK
IF(me .eq. 0) WRITE(*,*) 'ITEST ==> GK Improved Sugama'
ELSE
COLLISIONTI => ImprovedSugamaTDK
IF(me .eq. 0) WRITE(*,*) 'ITEST ==> DK Improved Sugama'
ENDIF
CASE(6) ! .... zeroth order Hirshman-Sigmar-Clarke operator
!
COLLISIONTI => hirshmansigmar0T
IF(me .eq. 0) WRITE(*,*) 'ITEST ==> DK zeroth order Hirshman-Sigmar-Clarke'
CASE(0)
COLLISIONTI => BUFFOPERATORT
CASE DEFAULT
IF(me .eq. 0 ) write(*,*) 'Operator model not defined....'
END SELECT
! Field component
SELECT CASE (IBACK)
CASE(1) ! ... coulomb
IF(GKI) THEN
!! COLLISIONFI => coulombFGK
IF(me .eq. 0 ) WRITE(*,*) 'IBACK ==> GK Coulomb'
ELSE
COLLISIONFI => coulombFDK
IF(me .eq. 0 ) WRITE(*,*) 'IBACK ==> DK Coulomb'
ENDIF
CASE(3) ! .... Sugama collision operator
IF(GKI) THEN
COLLISIONFI => SugamaFGK
IF(me .eq. 0) WRITE(*,*) 'IBACK ==> GK Sugama'
ELSE
COLLISIONFI => SugamaFDK
IF(me .eq. 0) WRITE(*,*) 'IBACK ==> DK Sugama'
ENDIF
CASE(5) ! .... Sugama Improved collision operator
IF(GKI) THEN
COLLISIONFI => ImprovedSugamaFDK
IF(me .eq. 0) WRITE(*,*) 'IBACK ==> GK Improved Sugama'
ELSE
COLLISIONFI => ImprovedSugamaFDK
IF(me .eq. 0) WRITE(*,*) 'IBACK ==> DK Improved Sugama'
ENDIF
CASE(6) ! .... zeroth order Hirshman-Sigmar-Clarke operator
!
COLLISIONFI => hirshmansigmar0F
IF(me .eq. 0) WRITE(*,*) 'IBACK ==> DK zeroth order Hirshman-Sigmar-Clarke'
CASE(0)
COLLISIONFI => BUFFOPERATORF
CASE DEFAULT
IF(me .eq. 0 ) write(*,*) 'Operator model not defined....'
END SELECT
! ...
end subroutine set_operator_ie_model
!
!_______________________________________________________________________
!
subroutine set_operator_ee_model
! set ee collision operator model
implicit none
SELECT CASE (ESELF)
CASE(1) ! ... DK Self-Coulomb
IF(GKE) THEN
IF(me .eq. 0 ) WRITE(*,*) 'ESELF => GK Coulomb'
! COLLISIONSELFE => CoulombSelfGK
ELSE
IF(me .eq. 0 ) WRITE(*,*) 'ESELF => DK Coulomb'
COLLISIONSELFE => CoulombSelfDK
ENDIF
CASE(2) ! ... Lorentz pitch angle
COLLISIONSELFE => LorentzDK
IF(me .eq. 0 ) WRITE(*,*) 'ETEST ==> DK (only DK) Lorentz ( nu = const. and without field)'
CASE(3) ! .... Sugama collision operator
IF(GKE) THEN
COLLISIONSELFE => SugamaSelfGK
IF(me .eq. 0) WRITE(*,*) 'ESELF ==> GK Sugama'
ELSE
COLLISIONSELFE => SugamaSelfDK
IF(me .eq. 0) WRITE(*,*) 'ESELF ==> DK Sugama'
ENDIF
CASE(5) ! .... Improved Sugama collision operator
IF(GKE) THEN
COLLISIONSELFE => ImprovedSugamaSelfGK
IF(me .eq. 0) WRITE(*,*) 'ESELF ==> GK Improved Sugama'
ELSE
COLLISIONSELFE => ImprovedSugamaSelfDK
IF(me .eq. 0) WRITE(*,*) 'ESELF ==> DK Improved Sugama'
ENDIF
CASE(6) ! .... zeroth order Hirshman-Sigmar-Clarke operator
!
COLLISIONSELFE => hirshmansigmar0self
IF(me .eq. 0) WRITE(*,*) 'ESELF ==> DK zeroth order Hirshman-Sigmar-Clarke'
CASE(8)
! pitch-angle operator with nu=nuD and field momentum restoring term
IF(GKE) THEN
COLLISIONSELFE => pitchselfGK
IF(me .eq. 0) WRITE(*,*) 'ESELF ==> GK pitch-angle scattering operator (nu=nuD and field component)'
ELSE
COLLISIONSELFE => pitchselfDK
IF(me .eq. 0) WRITE(*,*) 'ESELF ==> DK pitch-angle scattering operator (nu=nuD and field component)'
ENDIF
CASE(10)
! dougherty
COLLISIONSELFE => doughertyselfDK
IF(me .eq. 0) WRITE(*,*) 'ESELF ==> DK Dougherty'
CASE(0)
COLLISIONSELFE => BUFFOPERATORT
CASE DEFAULT
IF(me .eq. 0 ) write(*,*) 'Operator model not defined....'
END SELECT
! ...
end subroutine set_operator_ee_model
!
!_______________________________________________________________________
!
subroutine set_operator_ii_model
! set ii collision operator model
implicit none
SELECT CASE (ISELF)
CASE(1) ! ... DK Self-Coulomb
IF(GKI) THEN
IF(me .eq. 0 ) WRITE(*,*) 'ISELF => GK Coulomb'
! COLLISIONSELFI => CoulombSelfGK
ELSE
IF(me .eq. 0 ) WRITE(*,*) 'ISELF => DK Coulomb'
COLLISIONSELFI => CoulombSelfDK
ENDIF
CASE(3) ! .... Sugama collision operator
IF(GKI) THEN
COLLISIONSELFI => SugamaSelfGK
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> GK Sugama'
ELSE
COLLISIONSELFI => SugamaSelfDK
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> DK Sugama'
ENDIF
CASE(4)
IF( GKI) THEN
COLLISIONSELFI => pitchTGK
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> GK pitch-angle with nu = nuD(v) (without field)'
ELSE
COLLISIONSELFI => pitchTDK
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> DK pitch-angle with nu = nuD(v) (without field)'
ENDIF
CASE(5) ! .... Sugama Improved collision operator
IF(GKI) THEN
COLLISIONSELFI => ImprovedSugamaSelfGK
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> GK Improved Sugama'
ELSE
COLLISIONSELFI => ImprovedSugamaSelfDK
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> DK Improved Sugama'
ENDIF
CASE(6) ! .... zeroth order Hirshman-Sigmar-Clarke operator
!
COLLISIONSELFI => hirshmansigmar0self
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> DK zeroth order Hirshman-Sigmar-Clarke (only in DK)'
CASE(7) ! ... GK Abel collision operator
!
IF(GKI) THEN
COLLISIONSELFI => abelselfGK
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> GK Abel'
ELSE
COLLISIONSELFI => abelselfDK
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> DK Abel'
ENDIF
CASE(8)
! pitch-angle operator with nu=nuD and field momentum restoring term
IF(GKI) THEN
COLLISIONSELFI => pitchselfGK
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> GK pitch-angle scattering operator (nu=nuD and field component)'
ELSE
COLLISIONSELFI => pitchselfDK
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> DK pitch-angle scattering operator (nu=nuD and field component)'
ENDIF
CASE(9)
COLLISIONSELFI => coulombSelfGK_polarization
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> GK Coulomb polarization'
CASE(10)
! dougherty
COLLISIONSELFI => doughertyselfDK
IF(me .eq. 0) WRITE(*,*) 'ISELF ==> DK Dougherty'
CASE(0)
COLLISIONSELFI => BUFFOPERATORT
CASE DEFAULT
IF(me .eq. 0 ) write(*,*) 'Operator model not defined....'
END SELECT
end subroutine set_operator_ii_model
!
!_______________________________________________________________________
!
SUBROUTINE BUFFOPERATORT(l,k,rCabT)
! Abstract test particle operator
! Test routines/ field operator
IMPLICIT NONE
!
INTEGER,INTENT(in) :: l,k
TYPE(FM),DIMENSION(:),INTENT(inout) :: rCabT
!
! Local variables
INTEGER :: p,j,icol,irow
!
irow = numba(l,k)
DO p=0,Pmaxa
DO j=0,Jmaxa
icol = numba(p,j)
rCabT(icol) = 0._dp
ENDDO
ENDDO
END SUBROUTINE BUFFOPERATORT
!
!_______________________________________________________________________
!
SUBROUTINE BUFFOPERATORF(l,k,rCabF)
! Abstract back reaction operator
! Test routines back-reaction operator
USE prec_const
IMPLICIT NONE
!
INTEGER,INTENT(in) :: l,k
TYPE(FM), DIMENSION(:),INTENT(inout) :: rCabF
!
! Local variables
INTEGER :: p,j,icol,irow
!
irow = numba(l,k)
DO p=0,Pmaxb
DO j=0,Jmaxb
icol = numbb(p,j)
rCabF(icol) = 0._dp
ENDDO
ENDDO
END SUBROUTINE BUFFOPERATORF
!
!_______________________________________________________________________
!
END MODULE operator_model
c4science · Help