Homec4science
Diffusion COSOlver (new_coulomb) Browse

cosolver/src/ei_colls_mod.f90
83b8f38f6c51new_coulomb

Last Change
Raw File

ei_colls_mod.f90
View Options

MODULE ei_colls
! electron-ion collisions module
USE PREC_CONST
USE MODEL
USE BASIC
USE BASIC_MPI
use grid
USE ARRAY, only : CeiTdp,CeiFdp,rCeiT,rCeiF
USE OPERATOR_MODEL
USE OUTPUT
use auxval
USE restart
use gkcoulomb
IMPLICIT NONE
PROCEDURE(eval_CeiT), POINTER :: evaluate_CeiT_collisional_matrix => null()
PROCEDURE(eval_CeiF), POINTER :: evaluate_CeiF_collisional_matrix => null()
ABSTRACT INTERFACE
SUBROUTINE eval_CeiT
! Empty
END SUBROUTINE eval_CeiT
END INTERFACE
ABSTRACT INTERFACE
SUBROUTINE eval_CeiF
! Empty
END SUBROUTINE eval_CeiF
END INTERFACE
CONTAINS
SUBROUTINE ei_colls_control
! Set electron-ions basic/model
IMPLICIT NONE
!
IF(me_e .eq. 0) WRITE(*,*) '===== Electron-Ion Collisions ====='
IF(me_e .eq. 0) WRITE(*,*) 'Set Electron-Ion Collision ...'
CALL set_ei_colls
IF( ETEST .ne. 0) THEN
IF(me_e .eq. 0) WRITE(*,*) 'Construct collisional matrices CeiT ... '
CALL evaluate_auxval_test
call set_CeiT_collisional_matrix
CALL evaluate_CeiT_collisional_matrix
ENDIF
IF( EBACK .ne. 0) THEN
IF(me_e .eq. 0) WRITE(*,*) 'Construct collisional matrices CeiF ... '
call evaluate_auxval_field
call set_CeiF_collisional_matrix
CALL evaluate_CeiF_collisional_matrix
ENDIF
!
END SUBROUTINE ei_colls_control
!
!------------------------------------------------
!
SUBROUTINE set_ei_colls
! Set electron-ions basic/model
IMPLICIT NONE
!
CALL set_model('ei')
CALL set_basic('ei')
!
END SUBROUTINE set_ei_colls
!
!------------------------------------------------
!
! TEST COMPONENT
!
SUBROUTINE set_CeiT_collisional_matrix
! Evaluate the electron-ion test collisional matrix
IMPLICIT NONE
!
!
IF( ETEST .ne. 0 ) THEN
IF(IFGKCOULOMB) THEN
evaluate_CeiT_collisional_matrix => CeiT_gk_coulomb
call set_gkcoulomb
! set the perpendicular wavenumber
!
bfm_ = bafm_
bpfm_ = bafm_
!
IF( .not. GKC_USE_FULL) THEN
call load_gk_coulomb_coeffs('eiT')
ELSE
call set_tabljpmf('t')
ENDIF
!
ELSE
!
evaluate_CeiT_collisional_matrix => CeiT_dflt
!
ENDIF
ELSE
evaluate_CeiT_collisional_matrix => CeiT_zeros_dflt
ENDIF
!
END SUBROUTINE set_CeiT_collisional_matrix
!
!----------------------------------------------------
!
SUBROUTINE CeiT_dflt
! Evaluate the electron-ion collisional matrix
! Computes the test collisional matrix.
!
!
IMPLICIT NONE
!
! Local variables
INTEGER :: irow,irow_tmp
INTEGER, DIMENSION(2) :: lk
INTEGER :: istep, lbar_start
lbar_start = lbare_s_l
istep=1
!
! Test-part
IF( me .eq. 0 ) write(*, '(a,1x, i5,a)' ) 'CeiT [x/ ', lbare_e_l ,']:'
!
IF (ETEST .ne. 0) THEN
DO irow=lbar_start,lbare_e_l
! Get Hermite-Laguerre indices
irow_tmp = rows_e(irow)
lk = invnumbe(irow_tmp)
rCeiT(:)= TO_FM(0)
write(nscr,'(a)', advance = 'no') '.'
flush(nscr)
CALL COLLISIONTE(lk(1),lk(2),rCeiT)
CeiTdp(irow,:) = TO_DP(rCeiT(:))
istep = istep +1
ENDDO
ENDIF
!
!
END SUBROUTINE CeiT_dflt
!
!--------------------------------------------------------------
!
SUBROUTINE CeiT_gk_coulomb
! Evaluate electron-ion test GK Coulomb
use restart
use gkcoulomb
implicit none
INTEGER :: l,k,irow, icol, ii
INTEGER :: j,n,np,istep
INTEGER :: lbar_start, count
INTEGER, DIMENSION(4) :: lbarjnnp
INTEGER, DIMENSION(2) :: lk
!
!
!
! initialize indices
lbar_start = lbare_s_l
istep=1
!
IF( me .eq. 0 ) write(*,*) 'CeiT [x / ', numbe(Pmaxe,Jmaxe),'] :'
!
DO irow=lbar_start,lbare_e_l
lbarjnnp = rows_e_4dim(irow,1:4)
! Hermite-Laguerre indices
lk = invnumbe(lbarjnnp(1))
j = lbarjnnp(2)
n = lbarjnnp(3)
np = lbarjnnp(4)
write(nscr,'(a)', advance = 'no') '.'
flush(nscr)
rCeiT(:) = ZEROFM
CALL coulombTGK(lk(1),lk(2), j, n, np, rCeiT)
CeiTdp(irow,:) = TO_DP(rCeiT(:))
istep = istep +1
ENDDO
! Finalize GK Coulomb by performing summation over (j,np)
IF( nprocs > 1 ) THEN
DO icol =1, numbe( Pmaxe, Jmaxe)
count = (lbare_e_l - lbare_s_l +1 )
call mpi_gather( CeiTdp(:, icol) , count, MPI_DOUBLE_PRECISION &
, CeiTdp_global(:, icol), count, MPI_DOUBLE_PRECISION, 0, comm_e, ierr)
ENDDO
ELSE
CeiTdp_global = CeiTdp
ENDIF
CeiTdp_finalized = 0._dp
IF( me_e .eq. 0) THEN
DO irow = 1, numbe( Pmaxe, Jmaxe)
DO ii = 1, lbaremax
if( rows_e_4dim( ii, 1 ) .eq. irow) THEN
CeiTdp_finalized( irow, :) = CeiTdp_finalized( irow, :) &
+ CeiTdp_global( ii,:)
ENDIF
ENDDO
ENDDO
ENDIF
!
END SUBROUTINE CeiT_gk_Coulomb
!
!------------------------------------------------
!
SUBROUTINE CeiT_zeros_dflt
! Evaluate the electron-ion collisional matrix
! Computes the test collisional matrix.
!
!
IMPLICIT NONE
!
! Local variables
INTEGER :: irow,irow_tmp
INTEGER, DIMENSION(2) :: lk
!
IF( me .eq. 0 ) write(*, '(a,1x, i5,a)' ) 'CeiT [x/ ', numbe(Pmaxe,Jmaxe) ,']:'
! Test-part
IF (ETEST .ne. 0) THEN
DO irow=lbare_s_l,lbare_e_l
! Get Hermite-Laguerre indices
irow_tmp = rows_e(irow)
lk = invnumbe(irow_tmp)
rCeiT(:)= TO_FM(0)
write(nscr,'(a)', advance = 'no') '.'
flush(nscr)
CeiTdp(irow,:) = TO_DP(rCeiT(:))
ENDDO
ENDIF
!
!
END SUBROUTINE CeiT_zeros_dflt
!
!--------------------------------------------------------------
!
! FIELD COMPONENT
!
SUBROUTINE set_CeiF_collisional_matrix
! Evaluate the electron-ion collisional matrix
IMPLICIT NONE
!
!
IF (EBACK .ne. 0 ) THEN
IF(IFGKCOULOMB) THEN
!
evaluate_CeiF_collisional_matrix => CeiF_gk_coulomb
!
call set_gkcoulomb
!
! set the perpendicular wavenumber
!
bfm_ = bafm_
bpfm_ = bbfm_
!
IF (.not. GKC_USE_FULL) THEN
call load_gk_coulomb_coeffs('eiF')
ELSE
call set_tabljpmf('f')
ENDIF
!
ELSE
evaluate_CeiF_collisional_matrix =>CeiF_dflt
!
ENDIF
ELSE
evaluate_CeiF_collisional_matrix => CeiF_zeros_dflt
ENDIF
!
END SUBROUTINE set_CeiF_collisional_matrix
!
!----------------------------------------------------
SUBROUTINE CeiF_dflt
! Evaluate the electron-ion collisional matrix
! Computes the back-reaction collisional matrix.
!
!
IMPLICIT NONE
!
INTEGER :: irow,irow_tmp, lbar_start, istep
INTEGER, DIMENSION(2) :: lk
lbar_start = lbare_s_l
istep=1
IF( me .eq. 0 ) write(*, '(a,1x, i5,a)' ) 'CeiF [x/ ', lbare_e_l ,']:'
! Back-Reaction
IF (EBACK .ne. 0) THEN
DO irow=lbar_start,lbare_e_l
! Get Hermite-Laguerre indices
irow_tmp = rows_e(irow)
lk = invnumbe(irow_tmp)
write(nscr,'(a)', advance = 'no') '.'
flush(nscr)
rCeiF(:) = TO_FM(0)
CALL COLLISIONFE(lk(1),lk(2),rCeiF)
CeiFdp(irow,:) = TO_DP(rCeiF(:))
istep = istep +1
ENDDO
ENDIF
!
END SUBROUTINE CeiF_dflt
!
!--------------------------------------------
!
SUBROUTINE CeiF_gk_coulomb
! Evaluate electron-ion field GK Coulomb
use restart
use gkcoulomb
implicit none
INTEGER :: l,k,irow, icol, ii
INTEGER :: j,n,np,istep
INTEGER :: lbar_start, count
INTEGER, DIMENSION(4) :: lbarjnnp
INTEGER, DIMENSION(2) :: lk
!
!
! initialize indices
lbar_start = lbare_s_l
istep=1
!
IF( me .eq. 0 ) write(*, '(a,1x, i5,a)' ) 'CeiF [x/ ', numbe(Pmaxe,Jmaxe) ,']:'
!
DO irow=lbar_start,lbare_e_l
lbarjnnp = rows_e_4dim(irow,1:4)
! Hermite-Laguerre indices
lk = invnumbe(lbarjnnp(1))
j = lbarjnnp(2)
n = lbarjnnp(3)
np = lbarjnnp(4)
write(nscr,'(a)', advance = 'no') '.'
flush(nscr)
rCeiF(:) = ZEROFM
CALL coulombFGK(lk(1),lk(2),j,n,np,rCeiF)
CeiFdp(irow,:) = TO_DP(rCeiF(:))
! save current state
istep = istep +1
ENDDO
! Finalize GK Coulomb by performing summation over (j,np)
IF( nprocs > 1 ) THEN
DO icol =1, numbe( Pmaxe, Jmaxe)
count = (lbare_e_l - lbare_s_l +1 )
call mpi_gather( CeiFdp(:, icol) , count, MPI_DOUBLE_PRECISION &
, CeiFdp_global(:, icol), count, MPI_DOUBLE_PRECISION, 0, comm_e, ierr)
ENDDO
ELSE
CeiFdp_global = CeiFdp
ENDIF
CeiFdp_finalized = 0._dp
IF( me_e .eq. 0) THEN
DO irow = 1, numbe( Pmaxe, Jmaxe)
DO ii = 1, lbaremax
if( rows_e_4dim( ii, 1 ) .eq. irow) THEN
CeiFdp_finalized( irow, :) = CeiFdp_finalized( irow, :) &
+ CeiFdp_global( ii,:)
ENDIF
ENDDO
ENDDO
ENDIF
END SUBROUTINE CeiF_gk_Coulomb
!
!--------------------------------------------------
!
SUBROUTINE CeiF_zeros_dflt
! Evaluate the electron-ion collisional matrix
! Computes the back-reaction collisional matrix.
!
!
IMPLICIT NONE
!
INTEGER :: irow,irow_tmp
INTEGER, DIMENSION(2) :: lk
! Back-Reaction
IF (EBACK .ne. 0) THEN
DO irow=lbare_s_l,lbare_e_l
! Get Hermite-Laguerre indices
irow_tmp = rows_e(irow)
lk = invnumbe(irow_tmp)
write(*,*) 'CeiF: ',lk(1),'/',Pmaxe,' ,',lk(2),'/',Jmaxe
rCeiF(:) = TO_FM(0)
CeiFdp(irow,:) = TO_DP(rCeiF(:))
ENDDO
ENDIF
!
!
END SUBROUTINE CeiF_zeros_dflt
!
END MODULE ei_colls
c4science · Help