Homec4science
Diffusion FENNECS: Finite Element Non-Neutral Electron Cloud Simulator (geom_testpardiso) Browse

fennecs/src/auxval.f90
580212fe518bgeom_testpardiso

Last Change
Raw File

auxval.f90
View Options

SUBROUTINE auxval
!
USE constants
USE basic
USE fields
USE beam
!
! Set auxiliary values
!
IMPLICIT NONE
!
INTEGER:: i
!________________________________________________________________________________
IF(mpirank .eq. 0) WRITE(*,'(a/)') '=== Set auxiliary values ==='
!________________________________________________________________________________
!
! Total number of intervals
nr=sum(nnr)
! Normalisation constants
qsim=pi*(plasmadim(2)-plasmadim(1))*(plasmadim(4)**2-plasmadim(3)**2)*n0*elchar/nplasma
msim=abs(qsim)/elchar*me
vnorm=vlight
tnorm=1/sqrt(abs(n0)*elchar*elchar/me/eps_0)
rnorm=vnorm*tnorm
bnorm=B0
enorm=vlight*bnorm
phinorm=enorm*rnorm
! Normalised boundary conditions
potinn=potinn/phinorm
potout=potout/phinorm
! Characteristic frequencies and normalised volume
omegac=sign(elchar,qsim)/me*B0
omegap=sqrt(elchar**2*abs(n0)/me/eps_0)
V=pi*(plasmadim(2)-plasmadim(1))*(plasmadim(4)**2-plasmadim(3)**2)/rnorm/rnorm/rnorm
IF(mpirank .eq. 0) THEN
IF(omegap.GT.omegac) THEN
WRITE(*,'(a,3(1pe12.3))') 'omegap, omegac, omegap/omegac', omegap, omegac, omegap/omegac
ELSE
WRITE(*,'(a,3(1pe12.3))') 'omegap, omegac, omegac/omegap', omegap, omegac, omegac/omegap
END IF
END IF
! Construction of the mesh rgrid in r and zgrid in z and its normalisation
CALL mesh
rgrid=rgrid/rnorm
zgrid=zgrid/rnorm
dz=dz/rnorm
dr=dr/rnorm
! Define Zindex bounds for the MPI process in the case of sequential run
ALLOCATE( Zbounds(0:mpisize), Nplocs_all(0:mpisize-1))
Zbounds(0) = 0
Zbounds(mpisize) = nz
IF(mpisize.gt.1) THEN
leftproc=mpirank-1
IF(mpirank .eq. 0 .AND. partperiodic) THEN
leftproc = mpisize-1
ELSE IF (mpirank .eq. 0) THEN
leftproc=-1
END IF
rightproc = mpirank+1
IF(mpirank .eq. mpisize-1 .AND. partperiodic) THEN
rightproc = 0
ELSE IF (mpirank .eq. mpisize-1) THEN
rightproc=-1
END IF
ELSE
leftproc=-1
rightproc=-1
END IF
WRITE(*,*) "mpirank, left, right", mpirank, leftproc, rightproc
! Initialize the neighbors communicators
!CALL init_mpicomms(mpirank, mpisize, leftproc, rightproc)
! Auxiliary vectors
ALLOCATE(vec1((nz+1)*(nr+1)),vec2((nr+1)*(nz+1)))
DO i=0,nr
vec1(i*(nz+1)+1:(i+1)*(nz+1))=zgrid!(0:nz)
vec2(i*(nz+1)+1:(i+1)*(nz+1))=rgrid(i)
END DO
!________________________________________________________________________________
CONTAINS
!________________________________________________________________________________
SUBROUTINE mesh
USE basic, ONLY: zgrid, rgrid, nr, nnr, nz, dr, dz, lz, radii
INTEGER :: j
ALLOCATE(zgrid(0:nz),rgrid(0:nr))
dz=(lz(2)-lz(1))/nz
DO j=0,nz
zgrid(j)=j*dz+lz(1)
END DO
dr(1)=(radii(2)-radii(1))/nnr(1)
DO j=0,nnr(1)
rgrid(j)=radii(1)+j*dr(1)
END DO
dr(2)=(radii(3)-radii(2))/nnr(2)
DO j=1,nnr(2)
rgrid(nnr(1)+j)=radii(2)+j*dr(2)
END DO
dr(3)=(radii(4)-radii(3))/nnr(3)
DO j=1,nnr(3)
rgrid(nnr(1)+nnr(2)+j)=radii(3)+j*dr(3)
END DO
END SUBROUTINE mesh
!________________________________________________________________________________
END SUBROUTINE auxval
c4science · Help