Homec4science
Diffusion FENNECS: Finite Element Non-Neutral Electron Cloud Simulator (geom_testpardiso) Browse

fennecs/src/diagnose.f90
8ca7bf8f1164geom_testpardiso

Last Change
Raw File

diagnose.f90
View Options

SUBROUTINE diagnose(kstep)
!
! Diagnostics
!
USE basic
USE futils
USE hashtable
USE beam, ONLY : parts, epot, ekin, etot, etot0, ireducerequest, Nplocs_all
USE xg, ONLY : initw, updt_xg_var
USE mpi
IMPLICIT NONE
!
INTEGER, INTENT(in) :: kstep
!
! Local vars and arrays
INTEGER, PARAMETER :: BUFSIZE = 20
CHARACTER(len=128) :: str, fname
INTEGER :: partdensitystatus(MPI_STATUS_SIZE)
! Only process 0 should save on file
IF(mpirank .ne. 0) RETURN
!________________________________________________________________________________
! 1. Initial diagnostics
IF( kstep .EQ. 0) THEN
!
WRITE(*,'(a)') ' Initial diagnostics'
!
! 1.1 Initial run or when NEWRES set to .TRUE.
!
IF( .NOT. nlres .OR. newres) THEN
CALL creatf(resfile, fidres)
WRITE(*,'(3x,a,a)') TRIM(resfile), ' created'
!
! Label the run
IF( LEN_TRIM(label1).GT.0 ) CALL attach(fidres, "/", "label1", TRIM(label1))
IF( LEN_TRIM(label2).GT.0 ) CALL attach(fidres, "/", "label2", TRIM(label2))
IF( LEN_TRIM(label3).GT.0 ) CALL attach(fidres, "/", "label3", TRIM(label3))
IF( LEN_TRIM(label4).GT.0 ) CALL attach(fidres, "/", "label4", TRIM(label4))
!
! Job number
jobnum = 0
!
! Data group
CALL creatg(fidres, "/data", "data")
CALL creatg(fidres, "/data/var0d", "0d history arrays")
CALL creatg(fidres, "/data/input.", "input")
CALL creatg(fidres, "/data/var1d","1d history arrays")
CALL creatg(fidres, "/data/part", "part phase space")
CALL creatg(fidres, "/data/fields", "Electro static potential and Er Ez fields")
!
! File group
CALL creatg(fidres, "/files", "files")
CALL attach(fidres, "/files", "jobnum", jobnum)
CALL putarr(fidres, "/data/var1d/rgrid", rgrid)
CALL putarr(fidres, "/data/var1d/zgrid", zgrid)
! Part and fields vectors
! Initialize time-dependent particle variables
CALL creatd(fidres, 1, SHAPE(parts%R), "/data/part/R", "R")
CALL creatd(fidres, 1, SHAPE(parts%Z), "/data/part/Z", "Z")
CALL creatd(fidres, 1, SHAPE(parts%UZ), "/data/part/UR", "UZ")
CALL creatd(fidres, 1, SHAPE(parts%UR), "/data/part/UZ", "UR")
CALL creatd(fidres, 1, SHAPE(parts%UTHET), "/data/part/UTHET", "UTHET")
CALL creatd(fidres, 1, SHAPE(parts%Rindex), "/data/part/Rindex", "Rindex")
CALL creatd(fidres, 1, SHAPE(parts%Zindex), "/data/part/Zindex", "Zindex")
CALL creatd(fidres, 1, SHAPE(parts%pot), "/data/part/pot", "pot")
CALL creatd(fidres, 1, SHAPE(pot), "/data/fields/pot", "pot")
CALL creatd(fidres, 1, SHAPE(Er), "/data/fields/Er", "Er")
CALL creatd(fidres, 1, SHAPE(Ez), "/data/fields/Ez", "Ez")
CALL creatd(fidres, 1, SHAPE(partdensity), "/data/fields/partdensity", "partdensity")
IF(mpisize .gt. 1) CALL creatd(fidres, 1, SHAPE(Nplocs_all), "/data/part/Nplocs_all", "Nplocs_all")
CALL putarr(fidres, "/data/fields/Br", Br)
CALL putarr(fidres, "/data/fields/Bz", Bz)
!
! 1.2 Restart run
!
ELSE
CALL cp2bk(resfile) ! backup previous result file
CALL openf(resfile, fidres)
WRITE(*,'(3x,a,a)') TRIM(resfile), ' open'
CALL getatt(fidres, "/files", "jobnum", jobnum)
jobnum = jobnum+1
WRITE(*,'(3x,a,i3)') "Current Job Number =", jobnum
CALL attach(fidres, "/files", "jobnum", jobnum)
END IF
!
! Add input namelist variables as attributes of /data/input
WRITE(str,'(a,i2.2)') "/data/input.",jobnum
CALL creatg(fidres, TRIM(str))
CALL attach(fidres, TRIM(str), "job_time", job_time)
CALL attach(fidres, TRIM(str), "extra_time", extra_time)
CALL attach(fidres, TRIM(str), "dt", dt)
CALL attach(fidres, TRIM(str), "tmax", tmax)
CALL attach(fidres, TRIM(str), "nrun", nrun)
CALL attach(fidres, TRIM(str), "nlres", nlres)
CALL attach(fidres, TRIM(str), "nlsave", nlsave)
CALL attach(fidres, TRIM(str), "newres", newres)
CALL attach(fidres, TRIM(str), "nz", nz)
CALL putarr(fidres, TRIM(str)//"/lz", lz)
CALL attach(fidres, TRIM(str), "nplasma", nplasma)
CALL attach(fidres, TRIM(str), "potinn", potinn)
CALL attach(fidres, TRIM(str), "potout", potout)
CALL attach(fidres, TRIM(str), "B0", B0)
CALL attach(fidres, TRIM(str), "Rcurv", Rcurv)
CALL attach(fidres, TRIM(str), "width", width)
CALL attach(fidres, TRIM(str), "n0", n0)
CALL attach(fidres, TRIM(str), "temp", temp)
CALL attach(fidres, TRIM(str), "it0d", it0d)
CALL attach(fidres, TRIM(str), "it2d", it2d)
CALL attach(fidres, TRIM(str), "itparts", itparts)
CALL attach(fidres, TRIM(str), "nlclassical", nlclassical)
CALL attach(fidres, TRIM(str), "nlPhis", nlPhis)
CALL attach(fidres, TRIM(str), "qsim", qsim)
CALL attach(fidres, TRIM(str), "msim", msim)
CALL attach(fidres, TRIM(str), "V", V)
CALL putarr(fidres, TRIM(str)//"/femorder", femorder)
CALL putarr(fidres, TRIM(str)//"/ngauss", ngauss)
CALL putarr(fidres, TRIM(str)//"/nnr", nnr)
CALL putarr(fidres, TRIM(str)//"/radii", radii)
CALL putarr(fidres, TRIM(str)//"/plasmadim", plasmadim)
! Save STDIN of this run
WRITE(str,'(a,i2.2)') "/files/STDIN.",jobnum
INQUIRE(unit=lu_in, name=fname)
CALL putfile(fidres, TRIM(str), TRIM(fname))
CLOSE(lu_in)
!
! Initialize buffers for 0d history arrays
CALL htable_init(hbuf0, BUFSIZE)
CALL set_htable_fileid(hbuf0, fidres, "/data/var0d")
!
!
! Initialize Xgrafix
!
IF(nlxg) THEN
CALL initw
END IF
END IF
!________________________________________________________________________________
! 2. Periodic diagnostics
IF( kstep .NE. -1) THEN
!
IF(modulo(step,ittext).eq. 0 .or. nlend) THEN
WRITE(*,'(a,1x,i8.8,a1,i8.8,20x,a,1pe10.3)') &
& '*** Timestep (this run/total) =', step, '/', cstep, 'Time =', time
WRITE(*,'(a,4(1pe12.4))') 'Epot, Ekin, Etot, Eerr', epot, ekin, etot, etot-etot0
END IF
!________________________________________________________________________________
!
! 2.1 0d history arrays
!
IF(modulo(step,it0d).eq. 0 .or. nlend) THEN
CALL add_record(hbuf0, "time", "simulation time", time)
CALL add_record(hbuf0, "epot", "potential energy", epot)
CALL add_record(hbuf0, "ekin", "kinetic energy", ekin)
CALL add_record(hbuf0, "etot", "total energy", etot)
CALL htable_endstep(hbuf0)
IF(mpisize .gt. 1) CALL append(fidres, "/data/part/Nplocs_all", REAL(Nplocs_all,kind=db))
END IF
!
! 2.2 1d profiles
IF(modulo(step,it2d).eq. 0 .or. nlend) THEN
CALL append(fidres, "/data/fields/pot", pot)
CALL append(fidres, "/data/fields/Er", Er)
CALL append(fidres, "/data/fields/Ez", Ez)
CALL MPI_WAIT(ireducerequest(3), partdensitystatus, ierr)
CALL append(fidres, "/data/fields/partdensity", partdensity)
END IF
!
! 2.3 2d profiles
IF(modulo(step,itparts).eq. 0 .or. nlend) THEN
!PRINT*, 'write particles to file_____________________'
CALL append(fidres, "/data/part/R", parts%R)
CALL append(fidres, "/data/part/Z", parts%Z)
CALL append(fidres, "/data/part/UZ", parts%UZ)
CALL append(fidres, "/data/part/UR", parts%UR)
CALL append(fidres, "/data/part/UTHET", parts%UTHET)
CALL append(fidres, "/data/part/pot", parts%pot)
CALL append(fidres, "/data/part/Rindex", REAL(parts%Rindex,kind=db))
CALL append(fidres, "/data/part/Zindex", REAL(parts%Zindex,kind=db))
!
END IF
!
! 2.4 3d profiles
!
!
! 2.5 Xgrafix
!
IF(nlxg .AND. modulo(kstep,itgraph) .eq. 0 .AND. mpisize .eq. 1) THEN
call xgevent
CALL updt_xg_var
CALL xgupdate
END IF
!________________________________________________________________________________
! 3. Final diagnostics
ELSE
!
! Flush 0d history array buffers
CALL htable_hdf5_flush(hbuf0)
!
! Close all diagnostic files
CALL closef(fidres)
!________________________________________________________________________________
END IF
!
END SUBROUTINE diagnose
c4science · Help