Homec4science
Diffusion SCITAS Mini Cluster (master) Browse

scitas-mini-cluster/agamemnon/rack/scad_ressources/odroid.scad
050c8e634bb0master

Last Change
Raw File

odroid.scad
View Options

include <config.scad>
module standoff(pcb_heigth, pos) {
// http://www.farnell.com/datasheets/2019490.pdf
// http://www.farnell.com/datasheets/1702481.pdf
// http://www.farnell.com/cad/1902171.pdf
color("FloralWhite") translate(pos) {
translate([0, 0, 5]) cylinder(h=6, d=3, $fn = circle_res);
cylinder(h=5, d=6.35, $fn = 6);
translate([0, 0, 5 + pcb_heigth]) cylinder(h=2.4, d=6.15, $fn = 6);
///screw
translate([0, 0, -pvc_thickness - 2])
difference() {
union() {
cylinder(h=2, d=6.5, $fn = circle_res);
translate([0,0,2]) cylinder(h=4, d=3, $fn = circle_res);
}
cube([0.54, 6.5, 2], center=true);
}
}
}
module odroid_usb_port() {
usb_size = [13.2, 17.6, 14.27];
color("Silver") difference() {
union() {
translate([0,0,1.5]) {
cube([14.2, .5, 15.27]);
translate([0.5, 0.5, 0.5]) cube(usb_size);
}
translate([0.5, usb_size[1]-8+.5, 0]) cube([usb_size[0], 8, 2]);
}
translate([.8, -0.1, 2.3]) cube([12.4, 9.3, 4.9]);
translate([.8, -0.1, 2.3 + 3.6+4.9]) cube([12.4, 9.3, 4.9]);
}
color("White") {
translate([(14.2-10)/2, usb_size[1]-12, 0]) cube([10, 12, 2]);
translate([1.6, 0.6, 2.3 + 2.5]) cube([12.4-.8*2, 9.23, 2]);
translate([1.6, 0.6, 2.3 + 2.5 + 3.6+4.9]) cube([12.4-.8*2, 9.23, 2]);
}
}
module _odroid_rj45_hole(rj45_size) {
translate([rj45_size[0]/2 - 11.44/2, -0.1, 2.5])cube([11.44, 9.4, 6.88]);
translate([rj45_size[0]/2 - 6.12/2, -0.1, 2.5+6.88-0.1])cube([6.2, 10.5, 2]);
translate([rj45_size[0]/2 - 4/2, -0.1, rj45_size[2]-1.3-1])cube([4, 10.5, 1.2]);
}
module odroid_rj45() {
rj45_size = [16.24, 21.9, 13.4];
color("Silver") difference() {
cube(rj45_size);
// translate([0.15, 0.15, 0.15]) cube(rj45_size - [0.3, 0.3, 0.3]);
translate([1.1, -0.1, rj45_size[2] - 1.85 - 1.1]) cube([3.3, 0.3, 1.85]);
translate([rj45_size[0] - 1.1 - 3.3, -0.1, rj45_size[2] - 1.85 - 1.1]) cube([3.3, 0.3, 1.85]);
_odroid_rj45_hole(rj45_size);
}
color([0.2,0.2,0.2]) difference() {
translate([0.15, 0.15, 0.15]) cube(rj45_size - [0.3, 0.3, 0.3]);
_odroid_rj45_hole(rj45_size);
}
color("green") translate([1.1, 0, rj45_size[2] - 1.85 - 1.1]) cube([3.3, 0.3, 1.85]);
color("orange") translate([rj45_size[0] - 1.1 - 3.3, 0, rj45_size[2] - 1.85 - 1.1]) cube([3.3, 0.3, 1.85]);
}
module headers(nb_pins) {
translate([- nb_pins[0]*2.5/2, 1.25,0]) for(c = [0:nb_pins[1]-1]) {
translate([0, c*2.5, 0]) {
translate([1.25, 0, 0]) color("black") hull() {
cylinder(h = 2.55, d=2.5, $fn=8);
translate([(nb_pins[0]-1) * 2.5, 0, 0]) cylinder(h = 2.55, d=2.5, $fn=8);
}
color("gold") {
for(r = [0:nb_pins[0]-1]) {
translate([1.25 + 2.5*r, 0, -2.8]) cylinder(h = 11.2, d=0.7, $fn=4);
}
}
}
}
}
module odroid_radiator() {
color([0.1,0.1,0.1]) {
difference() {
cube([32, 40, 11.7]);
translate([-0.1, (40 - 5)/ 2,11.7-8.6])cube([34, 5, 10]);
for(h = [0:1]) {
translate([-0.1, 1.5+h*(1.3+1.2), 11.7-8.6]) cube([34, 1.3, 10]);
translate([-0.1, 40 - (1.3+1.5) - h*(1.3+1.2), 11.7-8.6]) cube([34, 1.3, 10]);
}
for(h = [0:5]) {
translate([-0.1, 6.4+h*(1.2+0.8), 11.7-8.6]) cube([34, 1.2, 10]);
translate([-0.1, 40 - (6.4 +1.2) - h*(1.2+0.8), 11.7-8.6]) cube([34, 1.3, 10]);
}
translate([-0.1, 5, 11]) cube([34, 30, 3]);
translate([-0.1, (40 - 13.7)/2, 9.6]) cube([34, 13.7, 5]);
translate([-0.1, (40 - 9)/2, 8.8]) cube([34, 9, 5]);
}
}
}
module odroid_uart() {
color("beige") difference() {
linear_extrude(5.8) polygon([[0, 0],[10.8, 0],[12.8, 2],[12.8,5.1],[0,5.1]]);
translate([0,0,1.4]) linear_extrude(5.8) offset(delta = -.8, chamfer=true)
polygon([[0, 0],[10.8, 0],[12.8, 2],[12.8,5.1],[0,5.1]]);
translate([-0.1, 2.1, 1.4]) cube([13, 1.5, 4.6 - 1.4]);
translate([-0.1, 3.1, 1.4]) cube([13, 0.5, 6]);
translate([-0.1, 2.1, -0.1]) cube([0.9, 1.5, 1.6]);
translate([12, 2.1, -0.1]) cube([0.9, 1.5, 1.6]);
translate([-0.1, 2.1, -0.1]) cube([0.9, 3.2, 1]);
translate([12, 2.1, -0.1]) cube([0.9, 3.2, 1]);
translate([-0.1, 5.1-0.6, -0.1]) cube([13, 3.2, 1]);
}
for(p = [0:3]) {
color("LightGoldenrodYellow") translate([2.2 + p * 2.4, 1.5, -2.8]) cylinder(d=0.7, h=9.1, $fn=4);
}
}
module _odroid_hdmi() {
offset(delta=-0.8, chamfer=true)
polygon([[0,2.4], [1.4,1.2], [2.4,0],[6.4,0], [6.4,15.2],
[2.4,15.2], [1.4,15.2-1.2], [0,15.2-2.4]]);
}
module odroid_hdmi() {
translate([11.3,0,0]) rotate([0,-90,0]) {
translate([0.9,-0.2,0]) {
color("silver") difference() {
linear_extrude(11.3) offset(r=0.6, $fn = 10) _odroid_hdmi();
translate([0,0,11.3-6.8]) linear_extrude(11.3) _odroid_hdmi();
}
color("DarkSlateGray") {
translate([0,0,11.3-6.8-0.25]) linear_extrude(0.3) _odroid_hdmi();
translate([3.5, (14.8-10)/2, 11.3-6.8]) cube([1,10,4.8]);
}
}
color("silver") linear_extrude(6) color("silver") {
square([6,0.4]);
translate([0,14.4]) square([6,0.4]);
}
}
}
module _odroid_micro_usb() {
hull() {
translate([1.8, 6.5]) circle(r=1, $fn=20);
translate([1.8, 1]) circle(r=1, $fn=20);
translate([1, 2]) circle(r=1, $fn=20);
translate([1, 5.5]) circle(r=1, $fn=20);
}
}
module odroid_micro_usb() {
translate([5.5,0,0]) rotate([0, -90, 0]) {
color("silver") difference() {
linear_extrude(5.5) _odroid_micro_usb();
translate([0,0,1]) linear_extrude(5.5) offset(delta=-0.4, chamfer=true)
_odroid_micro_usb();
}
color("DarkSlateGray") {
translate([0, 0, 1]) linear_extrude(0.1) offset(delta=-0.4, chamfer=true)
_odroid_micro_usb();
translate([1.7, (7.5-4)/2, 1]) cube([0.2, 4, 4]);
}
}
}
module odroid() {
hole_spacing = [49, 58];
odroid_bbox = [58, 87];
pcb_size = [56, 85];
pcb_heigth = 1.2;
pcb_offset = [(odroid_bbox[0] - pcb_size[0])/2, odroid_bbox[1] - pcb_size[1]];
pos = hole_spacing/2;
hole_center = [odroid_bbox[0]/2, odroid_bbox[1]-hole_spacing[1]/2 -3.4 ,0];
color([.2,.2,.2]) linear_extrude(pcb_heigth) union() {
difference(){
translate(pcb_offset)
hull() {
orig = [2.54, 2.54];
pos = pcb_size - orig;
translate(pos) circle(r=2.54, $fn = 20);
translate([pos[0],orig[1]]) circle(r=2.54, $fn = 20);
translate(orig) circle(r=2.54, $fn = 20);
translate([orig[0],pos[1]]) circle(r=2.54, $fn = 20);
}
translate(hole_center + pos) {
circle(d=3);
translate([0,-hole_spacing[1],0]) circle(d=3, $fn=circle_res);
}
translate(hole_center - pos) {
circle(d=3);
translate([0,hole_spacing[1],0]) circle(d=3, $fn=circle_res);
}
}
}
translate([0, 0, pcb_heigth]) {
//USB ports
usb_size = [14.2, 18.1, 16.77];
translate([pcb_offset[0] + pcb_size[0] - 2.4 - usb_size[0], pcb_offset[1] - 2, 0])
odroid_usb_port();
translate([pcb_offset[0] + pcb_size[0] - 2.4 - 3.7 - 2*usb_size[0], pcb_offset[1] - 2, 0])
odroid_usb_port();
// Ethernet
translate([pcb_offset[0] + 1.96, pcb_offset[1] - 1.6, 0])
odroid_rj45();
/// HDMI port
translate(pcb_offset + [-0.7, 45.46]) odroid_hdmi();
/// USB port
translate(pcb_offset + [-1, 70.6])
odroid_micro_usb();
/// IR
ir_size = [7.56, 2.9, 9.66];
translate (pcb_offset + pcb_size - [15.54, 4.7]) {
color("silver") cube(ir_size);
translate([ir_size[0]/2, 5-4.5/2, 6.7] )color("black") sphere(d=4.5, $fn=20);
}
/// GPIOs
translate(pcb_offset + pcb_size - [1+2.5, 7]) rotate([0, 0, 180]) {
headers([2,20]);
}
translate([pcb_offset[0]+2.75, pcb_offset[1] + pcb_size[1] - 18.8]) headers([2,1]);
translate([pcb_offset[0]+12.2+1.25, pcb_offset[1] + pcb_size[1] - 15]) rotate([0, 0, 180]) headers([1,7]);
translate(pcb_offset + [14.6,30]) odroid_radiator();
translate([pcb_offset[0]+14.2, pcb_offset[1] + pcb_size[1] - 5.09]) odroid_uart();
}
}
module odroid_standoff(fast, cable_clearance) {
hole_spacing = [49, 58];
odroid_bbox = [58, 87];
pcb_size = [56, 85];
pcb_heigth = 1.2;
pcb_offset = [(odroid_bbox[0] - pcb_size[0])/2, odroid_bbox[1] - pcb_size[1]];
pos = hole_spacing/2;
hole_center = [odroid_bbox[0]/2, odroid_bbox[1]-hole_spacing[1]/2 -3.4, 0];
if(cable_clearance) {
// USB cable clearance
color([.5,.5,.5,.5])
translate(pcb_offset + [-1, 70.6])
translate([-32, -(9.7 - 7.5)/2, 5 + pcb_heigth-1]) cube([32, 9.7, 6]);
}
if(fast) {
color([0.1,.1,.1,.5]) cube([58,87,23]);
} else {
translate([0, 0, 5]) {
odroid();
}
/// standoff with screws below the support
standoff(pcb_heigth, hole_center + pos);
standoff(pcb_heigth, hole_center - pos);
standoff(pcb_heigth, hole_center + pos - [0, hole_spacing[1]]);
standoff(pcb_heigth, hole_center - pos + [0, hole_spacing[1]]);
}
}
odroid_standoff(false, false);
c4science · Help