Homec4science
Diffusion slurm-accounts (master) Browse

slurm-accounts/lib/blib/ParseAccounts.pm
5a383306d713master

Last Change
Raw File

ParseAccounts.pm
View Options

# Accounts.pm - handling account-groups definitions
#
# Reads accounts.yaml definition file
# - Gets generic settings
# - Gets specific settings for the current slurm cluster
#
# Author : EPFL-SCITAS
# Date : March 2016
#
# Revisions
# January 2017: add fidis
# August 2018: get the settings for the current cluster only, passed to init()
package ParseAccounts;
use strict;
no strict "refs";
use YAML;
use Data::Dumper;
use Log;
# --- account generic settings ---
# associative array, indexed by accountname
# generic{$accountname} => parent ; slurm parent account
# generic{$accountname} => share ; slurm share
# generic{$accountname} => maxwall ; slurm maxwall
# generic{$accountname} => maxnodes ; slurm max nodes
my %generic;
# --- account specific settings for the target cluster passed to init() ---
# associative array, indexed by accountname
# cluster{$accountname} => parent ; slurm parent account
# cluster{$accountname} => share ; slurm share
# cluster{$accountname} => maxwall ; slurm maxwall
# cluster{$accountname} => maxnodes ; slurm max nodes
#
my %cluster;
# associative array for groups, indexed by group's uniqueIdentifier
# groups{$name} => [accounts]; list of slurm accounts associated to group
our %groups;
# the target cluster name
my $clustername;
# the YAML account definition file
my $filename;
# list of all acounts ordered from root to leaves of the account dependence tree
my @ordered_list_of_accounts;
sub all_accounts ()
{
return (sort keys(%generic));
}
# list of accounts in the account tree descendant order (root to leaves)
sub all_accounts_tree ()
{
return @ordered_list_of_accounts;
}
# get the specified account-key's value
sub get_value {
my ($accountname,$key) = @_;
my $value = $cluster{$accountname}{$key};
return $value if (defined($value) && $value ne "");
$value = $generic{$accountname}{$key};
return $value if (defined($value) && $value ne "");
# implicit rules, if "no" value specified:
if ($key eq "parent") {
# - parent=root for accounts with share > 1
# - parent=free for accounts with share == 1
return "free" if (get_value($accountname,"share") == 1);
return "root";
} elsif ($key eq "maxwall") {
# get slurm inherited value from parent account, if any
my $parent = get_value($accountname,"parent");
return "" if $parent eq "";
return "3-00:00:00" if $parent eq "root";
return get_value($parent,$key);
} elsif ($key eq "maxnodes") {
# get slurm inherited value from parent account, if any
my $parent = get_value($accountname,"parent");
return -1 if ($parent eq "" || $parent eq "root"); # -1 means "no" value for maxnodes
return get_value($parent,$key);
} elsif ($key eq "share") {
return 1;
}
# otherwise return "" witch means not "no" value set
return "";
}
sub account_parent($) {return get_value($_[0],"parent");}
sub account_share($) {return get_value($_[0],"share");}
sub account_maxwall($) {return get_value($_[0],"maxwall");}
sub account_maxnodes($) {return get_value($_[0],"maxnodes");}
sub print_groups ()
{
foreach my $groupname (sort keys(%groups)) {
print $groupname, ":", Log::array_to_string(@{$groups{$groupname}}), "\n";
}
}
sub print_accounts()
{
foreach my $accountname (sort keys(%generic)) {
print "generic(", $accountname, ")\n";
print " => parent : ", $generic{$accountname}{parent}, "\n";
print " => share : ", $generic{$accountname}{share}, "\n";
print " => maxwall : ", $generic{$accountname}{maxwall}, "\n";
print " => maxnodes : ", $generic{$accountname}{maxnodes}, "\n";
}
# print cluster specific values
foreach my $accountname (sort keys(%cluster)) {
print "\tcluster(", $accountname, ")\n";
print "\t => parent : ", $cluster{$accountname}{parent}, "\n";
print "\t => share : ", $cluster{$accountname}{share}, "\n";
print "\t => maxwall : ", $cluster{$accountname}{maxwall}, "\n";
print "\t => maxnodes : ", $cluster{$accountname}{maxnodes}, "\n";
}
}
sub print()
{
print "Account definitions for cluster ", $clustername, ":\n";
foreach my $accountname (all_accounts_tree()) {
print $filename, ":", $clustername, ":", $accountname, "\n";
print " => parent : ", get_value($accountname,"parent"), "\n";
print " => share : ", get_value($accountname,"share"), "\n";
print " => maxwall : ", get_value($accountname,"maxwall"), "\n";
print " => maxnodes : ", get_value($accountname,"maxnodes"), "\n";
}
}
# Return the list of accounts associated to a group
sub group_to_slurm_accounts($)
{
my ($groupname) = @_;
return () if !defined($groups{$groupname});
return @{$groups{$groupname}};
}
sub new_account($)
{
my ($accountname) = @_;
my %new=(parent => "", share => "", maxwall => "", maxnodes => "");
if (! defined($generic{$accountname})) {
$generic{$accountname} = {%new};
}
if (! defined($cluster{$accountname})) {
$cluster{$accountname} = {%new};
}
}
# recursive routine to build the top-down list of accounts, matching the account dependence tree
sub account_tree
{
my ($parent) = @_;
@ordered_list_of_accounts = () if $parent eq "root";
foreach my $accountname (keys(%generic)) {
if (get_value($accountname,"parent") eq $parent) {
if ( ! grep( /^$accountname$/, @ordered_list_of_accounts) ) {
push(@ordered_list_of_accounts,$accountname);
account_tree($accountname);
}
}
}
}
sub init($$)
{
my ($_clustername,$yaml_file) = @_;
# reset global variables
%groups = ();
%generic = ();
%cluster = ();
$clustername=$_clustername;
$filename = $yaml_file;
my $accountDefinitions = YAML::LoadFile($yaml_file);
# print Dumper($accountDefinitions);
my %accounts = %{$accountDefinitions};
foreach my $_account (keys(%accounts)) {
# names are case unsensitive
my $accountname=lc$_account;
new_account($accountname);
my %elems = %{$accounts{$_account}};
foreach my $elem (keys(%elems)) {
# print $accountname, " ", $elem, "\n";
if ($elem eq "groups") {
my @groups = @{$accounts{$_account}{groups}};
# print $account, " groups=", Log::array_to_string(@groups), "\n";
foreach my $groupname (@groups) {
$groupname=lc$groupname;
push(@{$groups{$groupname}},$accountname);
}
} elsif ($elem eq $clustername) {
for (keys(%{$accounts{$_account}{$clustername}})) {
$cluster{$accountname}{$_} = $accounts{$_account}{$clustername}{lc$_};
# print $clustername, " ", $accountname, " ", $_, "--->", $cluster{$accountname}{$_}, "\n";
}
} elsif (defined($generic{$accountname}{$elem})) {
$generic{$accountname}{$elem} = $accounts{$_account}{lc$elem};
# print " generic ", $accountname, " ", $elem, "--->", $generic{$accountname}{$elem}, "\n";
}
}
}
# get the list of accounts in the tree descendant order
account_tree("root");
}
1;
c4science · Help