Homec4science
Diffusion SpecMiCP / ReactMiCP (chloride) Browse

specmicp/cmake/SanitizerBuild.cmake
52a48c08d9b4chloride

Last Change
Raw File

SanitizerBuild.cmake
View Options

# SanitizerBuild
# ===============
#
# Define a new build type using the "-fsanitize=" options
# It can be activated the normal way : -DCMAKE_BUILD_TYPE=Sanitizer
#
# author : Fabien Georget
# This is part of the SpecMiCP build system
#This are the flags that may be included
set(ADDRESS_SANITIZER_FLAG "-fsanitize=address")
set(UNDEFINED_SANITIZER_FLAG "-fsanitize=undefined")
# test if the flags exists
include(CheckCXXCompilerFlag)
set(CMAKE_REQUIRED_FLAGS "-Werror ${ADDRESS_SANITIZER_FLAG}")
check_cxx_compiler_flag("${ADDRESS_SANITIZER_FLAG}" HAS_ADDRESS_SANITIZER)
set(CMAKE_REQUIRED_FLAGS "-Werror ${UNDEFINED_SANITIZER_FLAG}")
check_cxx_compiler_flag("${UNDEFINED_SANITIZER_FLAG}" HAS_UNDEFINED_SANITIZER)
unset(CMAKE_REQUIRED_FLAGS)
# if they exists add them
if (HAS_ADDRESS_SANITIZER)
set(FLAGS_SANITIZER "${ADDRESS_SANITIZER_FLAG} -fno-omit-frame-pointer")
endif()
if (HAS_UNDEFINED_SANITIZER)
set(FLAGS_SANITIZER "${FLAGS_SANITIZER} ${UNDEFINED_SANITIZER_FLAG}")
endif()
# -Wfloat-conversion -Winline -Weffc++ -Wold-style-cast -Woverloaded-virtual
set(SANITIZER_EXTRA_WARNINGS "-Wextra"
CACHE STRING "Extra warnings for the sanitizer build")
set( CMAKE_CXX_FLAGS_SANITIZER "-O1 -g -Wall -pedantic ${SANTIZER_EXTRA_WARNINGS} ${FLAGS_SANITIZER}" CACHE STRING
"Flags used by the C++ compiler during sanitizer builds."
FORCE )
set( CMAKE_C_FLAGS_SANITIZER "-O1 -g -Wall -pedantic ${SANTIZER_EXTRA_WARNINGS} ${FLAGS_SANITIZER}" CACHE STRING
"Flags used by the C compiler during sanitizer builds."
FORCE )
set( CMAKE_EXE_LINKER_FLAGS_SANITIZER
"${FLAGS_SANITIZER}" CACHE STRING
"Flags used for linking binaries during SANITIZER builds."
FORCE )
set( CMAKE_SHARED_LINKER_FLAGS_SANITIZER
"${FLAGS_SANITIZER}" CACHE STRING
"Flags used by the shared libraries linker during SANITIZER builds."
FORCE )
set( CMAKE_STATIC_LINKER_FLAGS_SANITIZER
"" CACHE STRING
"Flags used by the static libraries linker during SANITIZER builds."
FORCE )
mark_as_advanced(
CMAKE_CXX_FLAGS_SANITIZER
CMAKE_C_FLAGS_SANITIZER
CMAKE_EXE_LINKER_FLAGS_SANITIZER
CMAKE_SHARED_LINKER_FLAGS_SANITIZER
CMAKE_STATIC_LINKER_FLAGS_SANITIZER
)
# Update the documentation string of CMAKE_BUILD_TYPE for GUIs
set( CMAKE_BUILD_TYPE "${CMAKE_BUILD_TYPE}" CACHE STRING
"Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel Sanitizer."
FORCE )
c4science · Help