project(specmicp)
cmake_minimum_required(VERSION 2.8)

#######################  External Package #####################################
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")
find_package(Eigen3 REQUIRED)  # This module comes from the Eigen3 Package
find_package(CxxTest)          # Necessary if you want the tests

########################  Compilation flags #################################
if(UNIX)
   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -march=native -std=c++11")
   SET(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -O2 -Wall -pedantic")
   SET(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -O2 -DNDEBUG")
   message(STATUS "c++ flags ${CMAKE_CXX_FLAGS}")
else()
    message(WARNING "not tested !")
endif()


################ Directories #####################

set(PROJECT_TEST_DIR   ${PROJECT_SOURCE_DIR}/tests)
set(PROJECT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src)

# include
include_directories(${EIGEN3_INCLUDE_DIR})
include_directories(${PROJECT_SOURCE_DIR})

################ Modules ##########################

# -------- MiCPSolver ----------------

set(MICPSOLVER_DIR ${PROJECT_SOURCE_DIR}/micpsolver)

add_custom_target(specmisolver_inc SOURCES
    ${MICPSOLVER_DIR}/micpsolver.hpp
    ${MICPSOLVER_DIR}/micpsolver.inl
    ${MICPSOLVER_DIR}/micpprog.hpp
    ${MICPSOLVER_DIR}/ncp_function.hpp
    ${MICPSOLVER_DIR}/estimate_cond_number.hpp
)

# ------- SpecMiCP ---------------

set(SPECMICP_DIR ${PROJECT_SOURCE_DIR}/specmicp)

add_custom_target(specmic_inc SOURCES
    #${SPECMICP_DIR}/.hpp
    ${SPECMICP_DIR}/thermodata.hpp
)

set(SPECMICP_LIBFILE
    ${SPECMICP_DIR}/extended_system.cpp
    ${SPECMICP_DIR}/reduced_system.cpp
)

add_library(specmicp ${SPECMICP_LIBFILE})

# -------- Database ----------------

set(DATABASE_DIR ${PROJECT_SOURCE_DIR}/database)

set(DATABASE_LIBFILE
    ${DATABASE_DIR}/database.cpp
    ${DATABASE_DIR}/reader.cpp
    ${DATABASE_DIR}/selector.cpp
)

add_custom_target(data_incl SOURCES
    ${DATABASE_DIR}/common_def.hpp
    ${DATABASE_DIR}/data_container.hpp)

add_library(specmicp_database ${DATABASE_LIBFILE})

# ------- Utils ------------------

set(UTILS_DIR ${PROJECT_SOURCE_DIR}/utils)

add_custom_target(utils_inc SOURCES
    ${UTILS_DIR}/log.hpp)

# ------- Data -------------------

set(DATA_DIR ${CMAKE_CURRENT_SOURCE_DIR}/data)

set(DATABASE_LIST
        ${DATA_DIR}/specmicp_database.js
        ${DATA_DIR}/cemdata_specmicp.js
)

add_custom_target(data SOURCES ${DATABASE_LIST})

file(INSTALL ${DATABASE_LIST}
     DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/data/)

# ------ Documentation -----------


# add a target to generate API documentation with Doxygen
find_package(Doxygen)
if(DOXYGEN_FOUND)
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/doc/Doxyfile.in ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile @ONLY)
add_custom_target(doc
${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile
WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
COMMENT "Generating API documentation with Doxygen" VERBATIM
)
add_custom_target(citations SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/doc/citations.bib)
file(INSTALL ${CMAKE_CURRENT_SOURCE_DIR}/doc/citations.bib
     DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/doc/)
endif(DOXYGEN_FOUND)


# --------- Test ----------------------

# CXX Test
# ========

if(CXXTEST_FOUND)
    set(CXXTEST_USE_PYTHON TRUE)
    include_directories(${CXXTEST_INCLUDE_DIR})
    enable_testing()

    # MiCP Solver
    # ------------
    CXXTEST_ADD_TEST(test_cond_number
                     test_cond_number.cpp
                     ${PROJECT_TEST_DIR}/micpsolver/test_cond_number.hpp)

    CXXTEST_ADD_TEST(test_ncp_funtion
                     test_ncp_function.cpp
                     ${PROJECT_TEST_DIR}/micpsolver/test_ncp_function.hpp)

    CXXTEST_ADD_TEST(test_micpsolver
                     test_micpsolver.cpp
                     ${PROJECT_TEST_DIR}/micpsolver/test_micpsolver.hpp)

    # Database
    # --------

    CXXTEST_ADD_TEST(test_data_reader
                    test_data_reader.cpp
                    ${PROJECT_TEST_DIR}/database/test_data_reader.hpp)
    target_link_libraries(test_data_reader specmicp_database jsoncpp)


    CXXTEST_ADD_TEST(test_data_selector
                    test_data_selector.cpp
                    ${PROJECT_TEST_DIR}/database/test_data_selector.hpp)
    target_link_libraries(test_data_selector specmicp_database jsoncpp)


endif()

# Test 'Perso'
# ============

add_executable(thermocarbo ${PROJECT_TEST_DIR}/specmicp/thermocarbo.cpp)
target_link_libraries(thermocarbo specmicp specmicp_database jsoncpp)