Homec4science
Diffusion SpecMiCP / ReactMiCP (yaml/safe) Browse

specmicp/CMakeLists.txt
a4c639058982yaml/safe

Last Change
Raw File

CMakeLists.txt
View Options

####################################################
# #
# SpecMiCP : CMakeLists.txt #
# #
####################################################
project(specmicp)
cmake_minimum_required(VERSION 2.8.8)
# Configuration options
# ======================
# For an explanation of the options see the INSTALL file
option( SPECMICP_USE_OPENMP "Thread parallelisation of specmicp instances if available" ON )
option( SPECMICP_NO_DEBUG "Disable SpecMiCP assert" OFF )
option( SPECMICP_BUILD_STATIC "Build static libraries" OFF )
option( SPECMICP_BUILD_EXAMPLE "Build the examples" ON )
option( SPECMICP_DEBUG_EQUATION_FD_JACOBIAN "Use a finite difference jacobian is specmicp" OFF )
# PGO sequence
option( SPECMICP_PROFILE_GENERATE "Generate the profile for PGO optimization" OFF )
option( SPECMICP_PROFILE_USE "Use the generated profile for PGO optimization" OFF )
# LTO optimization
option( SPECMICP_LTO "Use link time optimization" OFF )
option( SPECMICP_LD_GOLD "Use GNU gold linker" ON )
# global variables
# ================
set(SPECMICP_VERSION 0.0.3)
# External Package
# ================
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${PROJECT_SOURCE_DIR}/cmake)
# OpenMP
#-------
# not required but recommended
if(SPECMICP_USE_OPENMP)
find_package(OpenMP)
endif()
# Boost
# -----
find_package(Boost REQUIRED)
include_directories(${Boost_INCLUDE_DIR})
# Eigen
# -----
find_package(Eigen3 REQUIRED) # This module comes from the Eigen3 Package
include_directories(${EIGEN3_INCLUDE_DIR})
# Eigen unsuported
# GMRES.h is really the file we are using/looking for
# If it doesn't exist then the solver will not be included in the list of the parse solvers
if(EXISTS "${EIGEN3_INCLUDE_DIR}/unsupported/Eigen/src/IterativeSolvers/GMRES.h")
add_definitions(-DEIGEN_UNSUPPORTED_FOUND)
include_directories("${EIGEN3_INCLUDE_DIR}/unsupported/")
endif()
# Yaml-cpp
# --------
include(FindPkgConfig)
pkg_check_modules(YAML REQUIRED yaml-cpp>=0.5)
include_directories(${YAML_INCLUDE_DIRS})
link_directories(${YAML_LIBRARY_DIRS})
# sanitizer
include(SanitizerBuild)
# compilation flags
# =================
# check the availability of :
# c++11
include(cxx11)
# -fuse-ld=gold
include(gold_linker)
# pgo optimization
include(pg_optimization)
# -fvisibility-hidden
include(visibility_flag)
# just a friendly warning
if(NOT UNIX)
message(WARNING "not tested !")
endif()
include(lto)
# set the flag
SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${CXX11_FLAG}")
if (OPENMP_FOUND)
SET( CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${OpenMP_C_FLAGS}")
SET( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${OpenMP_CXX_FLAGS}")
endif()
SET(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -Wall -pedantic")
##SET(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
message(STATUS "c++ flags : ${CMAKE_CXX_FLAGS}")
# Directories
#########################################################################
# 3rd party
# =========
# installation dir
# ----------------
# http://www.cmake.org/pipermail/cmake/2010-February/035466.html
# compute default library install dir
# library
# ------
set (_DEFAULT_LIBRARY_INSTALL_DIR lib)
if (EXISTS "${CMAKE_INSTALL_PREFIX}/lib32/" AND CMAKE_SIZEOF_VOID_P EQUAL 4)
set (_DEFAULT_LIBRARY_INSTALL_DIR lib32)
elif (EXISTS "${CMAKE_INSTALL_PREFIX}/lib64/" AND CMAKE_SIZEOF_VOID_P EQUAL 8)
set (_DEFAULT_LIBRARY_INSTALL_DIR lib64)
endif ()
# the library install dir
set(LIBRARY_INSTALL_DIR "${_DEFAULT_LIBRARY_INSTALL_DIR}" CACHE PATH "Installation directory for libraries")
set(STATIC_LIBRARY_INSTALL_DIR "${_DEFAULT_LIBRARY_INSTALL_DIR}/static" CACHE PATH "Installation directory for static libraries")
# make the library install dir an absolute path (can be important e.g. when using CONFIGURE_FILE to embed
# the library installation directory into a file)
if(NOT IS_ABSOLUTE "${LIBRARY_INSTALL_DIR}")
set(LIBRARY_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIBRARY_INSTALL_DIR}")
endif()
if(NOT IS_ABSOLUTE "${STATIC_LIBRARY_INSTALL_DIR}")
set(STATIC_LIBRARY_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${STATIC_LIBRARY_INSTALL_DIR}")
endif()
# include
#--------
set(INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/include/specmicp" CACHE PATH "Installation directories for the headers")
# share
#------
set(SHARE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/share/specmicp" CACHE PATH "Installation directories for the miscalleneous files...")
enable_testing(true)
# CPP API : SpecMiCP / ReactMiCP
#########################################################################
# the main source directory - the c++ api
set(SPECMICP_CPP_API ${CMAKE_CURRENT_SOURCE_DIR}/src)
include_directories(${SPECMICP_CPP_API})
add_subdirectory( ${SPECMICP_CPP_API} )
set(SPECMICP_LIBS specmicp specmicp_database specmicp_common ${YAML_LIBRARIES})
set(REACTMICP_LIBS reactmicp dfpm ${SPECMICP_LIBS} )
set(SPECMICP_STATIC_LIBS specmicp_static specmicp_database_static specmicp_common_static ${YAML_LIBRARIES})
set(REACTMICP_STATIC_LIBS reactmicp_static dfpm_static ${SPECMICP_STATIC_LIBS})
# Database
#########################################################################
add_subdirectory( data )
# Documentation
#########################################################################
# "common" documentation
# -----------------------
set(
DOCS_LIST
${CMAKE_CURRENT_SOURCE_DIR}/README.md
${CMAKE_CURRENT_SOURCE_DIR}/INSTALL
${CMAKE_CURRENT_SOURCE_DIR}/COPYING
)
add_custom_target(docs SOURCES ${DOCS_LIST})
install(FILES ${DOCS_LIST}
DESTINATION ${SHARE_INSTALL_DIR}
)
# scripts
# --------
add_subdirectory( scripts )
# Doxygen documentation
# ---------------------
add_subdirectory( doc )
# Tests
#########################################################################
add_subdirectory( tests )
# Examples
#########################################################################
add_subdirectory( examples )
c4science · Help