Homec4science
Diffusion tamaas (features/materials) Browse

tamaas/doc/SConscript
2f804a0f980efeatures/materials

Last Change
Raw File

SConscript
View Options

# -*- coding: utf-8 -*-
# @file
# @section LICENSE
#
# Copyright (©) 2016-2021 EPFL (École Polytechnique Fédérale de Lausanne),
# Laboratory (LSMS - Laboratoire de Simulation en Mécanique des Solides)
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published
# by the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program. If not, see <https://www.gnu.org/licenses/>.
from __future__ import print_function
import os
from os.path import join
from SCons.Script import Import, Glob, Dir, File
Import('main_env')
Import('libTamaas')
doc_env = main_env.Clone()
# Generating Doxyfile
doxyfile_target = doc_env.Substfile('doxygen/Doxyfile', 'doxygen/Doxyfile.in',
SUBST_DICT={
'@version@': '$version',
'@build_dir@': Dir('doxygen').path,
'@logo@': File('icon.svg').path,
'@src_dir@': Dir('#src').abspath,
})
# Generate Doxygen API documentation
doc_env.Tool('doxygen')
doxygen_target = doc_env.Doxygen('doxygen/xml/index.xml',
[doxyfile_target, 'icon.svg'])
# Adding all source files as dependencies
sources = []
for root, _, files in os.walk(Dir('#src').abspath):
sources += Glob(join(root, '*.hh'))
sources += Glob(join(root, '*.cpp'))
doc_env.Depends(doxygen_target, sources)
# Generate Sphinx User documentation
doc_env.Tool('sphinx')
sphinx_sources = [Glob('sphinx/source/*'), Glob('sphinx/source/figures/*')]
sphinx_targets = []
sphinx_targets.append(doc_env.Sphinx('sphinx/html/index.html', sphinx_sources))
sphinx_targets.append(doc_env.Sphinx('sphinx/tamaas.1', sphinx_sources))
doc_env.Depends(sphinx_targets, doxygen_target)
# Alias for both docs
doc_targets = [doxygen_target] + sphinx_targets
main_env.Alias('build-doc', doc_targets)
# Install target for documentation
doc_prefix = join(doc_env['prefix'], 'share', 'doc', 'tamaas')
man_prefix = join(doc_env['prefix'], 'share', 'man', 'man1')
doc_install = []
doc_install.append(doc_env.Install(target=doc_prefix,
source=sphinx_targets[0][0].dir))
doc_install.append(doc_env.Install(target=man_prefix,
source=sphinx_targets[1]))
main_env.Alias('install-doc', doc_install)
c4science · Help