Homec4science
Diffusion tamaas (features/materials) Browse

tamaas/python/SConscript
f6f9d433c7ecfeatures/materials

Last Change
Raw File

SConscript
View Options

# -*- mode:python; coding: utf-8 -*-
# vim: set ft=python:
# @file
# @section LICENSE
#
# Copyright (©) 2016-19 EPFL (École Polytechnique Fédérale de Lausanne),
# Laboratory (LSMS - Laboratoire de Simulation en Mécanique des Solides)
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published
# by the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program. If not, see <https://www.gnu.org/licenses/>.
from __future__ import print_function
import subprocess
from os.path import abspath, join
from SCons.Script import Import, Split, Copy, Dir
Import('main_env')
# Pybind11 wrapper
env_pybind = main_env.Clone(SHLIBPREFIX='')
# Remove pedantic warnings
cxx_flags = env_pybind['CXXFLAGS']
try:
del cxx_flags[cxx_flags.index('-pedantic')]
except ValueError:
pass
env_pybind.Tool(pybind11)
pybind_sources = Split("""
tamaas_module.cpp
wrap/core.cpp
wrap/percolation.cpp
wrap/surface.cpp
wrap/model.cpp
wrap/solvers.cpp
wrap/compute.cpp
wrap/test_features.cpp
""")
# Adding legacy wrap code
if main_env['legacy_bem']:
pybind_sources += ["wrap/bem.cpp"]
# Building the pybind library
tamaas_wrap = env_pybind.SharedLibrary(
target='tamaas/_tamaas',
source=pybind_sources,
LIBS=['Tamaas'],
)
# For some reason link happens too early
Import('libTamaas')
env_pybind.Depends(tamaas_wrap, libTamaas)
# Copying the __init__.py file with extra python classes
copy_env = env_pybind.Clone(
PRINT_CMD_LINE_FUNC=main_env['gen_print']("Copying", "red", main_env))
# Copying additional python files
python_files = """
compute.py
dumpers/__init__.py
dumpers/_helper.py
nonlinear_solvers/__init__.py
""".split()
targets = [tamaas_wrap]
targets += [
copy_env.Command(join('tamaas', f),
join(abspath(str(Dir('#python/tamaas'))), f),
Copy("$TARGET", "$SOURCE"))
for f in python_files
]
targets.append(copy_env.Command('MANIFEST.in', '#python/MANIFEST.in',
Copy("$TARGET", "$SOURCE")))
subst_env = env_pybind.Clone(
PRINT_CMD_LINE_FUNC=main_env['gen_print']("Generating", "yellow", main_env),
SUBST_DICT={
'@version@': '$version',
'@authors@': str(copy_env['authors']),
'@email@': '$email',
# TODO change when issue with unicode fixed
# '@copyright@': '$copyright,
# '@maintainer@': '$maintainer',
}
)
subst_env.Tool('textfile')
targets.append(subst_env.Substfile('setup.py.in'))
targets.append(subst_env.Substfile('tamaas/__init__.py.in'))
# Defining alias for python builds
main_env.Alias('build-py', targets)
# Checking if we can use pip to install (more convenient for end-user)
has_pip = subprocess.call([main_env['py_exec'], '-c', 'import pip']) == 0
# Current build directory
main_env['PYDIR'] = Dir('.')
# Setting command line for installation
if has_pip:
print('Using pip to install')
main_env['PYINSTALLCOM'] = '${py_exec} -m pip install $PYOPTIONS .'
main_env['PYDEVELOPCOM'] = '${py_exec} -m pip install $PYOPTIONS -e .'
else:
print('Using setup.py to install')
main_env['PYINSTALLCOM'] = '${py_exec} setup.py install $PYOPTIONS'
main_env['PYDEVELOPCOM'] = '${py_exec} setup.py develop $PYOPTIONS'
# Specify install target
python_install = main_env.Command(
join('$prefix', 'dummy_target'),
targets, main_env['PYINSTALLCOM'], PYOPTIONS='--prefix ${prefix}',
chdir=main_env['PYDIR'])
python_install_dev = main_env.Command(
join('$prefix', 'dummy_target_local'),
targets, main_env['PYDEVELOPCOM'], PYOPTIONS='--user',
chdir=main_env['PYDIR'])
main_env.Alias('install-python', python_install)
main_env.Alias('install-python-dev', python_install_dev)
c4science · Help