Homec4science
Diffusion COSOlver (improved_sugama) Browse

cosolver/GKCoulomb/Tljpmf/src/model_mod.f90
3c0a5500b5baimproved_sugama

Last Change
Raw File

model_mod.f90
View Options

module model
!
! model module contains the relevant physical parameters (e.g. mass, temperature)
use prec_const
use FMZM
implicit none
public
! physical parameters
real(dp), public, protected :: mu =1._dp ! m_e/m_i
real(dp), public, protected :: tau = 1._dp ! T_i0/T_e0
! collisions type: 'self', 'field', 'test'
character*10, public, protected :: coll_type ! set the test/field/ test + field
character*10, public, protected :: coll_ab ! set colliding species type
! electron-ion mass/temperature ratio, double precision
real(dp), public, protected :: sigmaei, sigmaaa,sigmaie
real(dp), public, protected :: tauei, tauie, tauaa
real(dp), public, protected :: sigma_ = 1._dp ! 0.0005289999999999_dp
real(dp), public, protected :: tau_ = 1._dp ! 100._dp
real(dp), public, protected :: chi_ = 1._dp !1._dp
! Multiple-Precision FM type
TYPE(FM), public, protected :: sigmafm_ ! mass ratio
TYPE(FM), public, protected :: taufm_ ! temperature ratio
TYPE(FM), public, protected :: chifm_ ! SQRT(tau/sigma) = vTa/vTb
! output labels
character(len=15), public:: strmu
character(len=15), public :: strtau
contains
!================================================================================
subroutine model_readinputs
! Read inputs physical input parameters
use basic, only: lu_in,me ,ierr
use prec_const
implicit none
character(len=8) :: fmt = '(f6.4)'
NAMELIST /MODEL_PAR/ coll_type, coll_ab, mu, tau
IF( me .ne. 0) GOTO 111
read(lu_in, MODEL_PAR)
write(*,MODEL_PAR)
111 CONTINUE
!
! Broadcast from PE 0 to
!
CALL MPI_bcast(mu,1,MPI_DOUBLE_PRECISION,0,MPI_COMM_WORLD,ierr)
CALL MPI_bcast(tau,1,MPI_DOUBLE_PRECISION,0,MPI_COMM_WORLD,ierr)
CALL MPI_bcast(coll_type, 10, MPI_CHARACTER, 0, MPI_COMM_WORLD, ierr)
CALL MPI_bcast(coll_ab, 10, MPI_CHARACTER, 0, MPI_COMM_WORLD, ierr)
! convert to string
write(strmu,fmt) mu
write(strtau,fmt) tau
! set electron-ion mass/temperature ratios !!
sigmaei = mu
sigmaie = 1/sigmaei
sigmaaa = 1._dp
tauei = 1/tau
tauie = tau
tauaa = 1._dp
! set model
SELECT CASE(coll_ab)
CASE ('ei')
IF( me .eq. 0) WRITE(*,*) 'electron-ion coll....'
call set_model('ei')
CASE ('ie')
IF( me .eq. 0) WRITE(*,*) 'ion-electron coll....'
call set_model('ie')
CASE ('ee')
IF( me .eq. 0) WRITE(*,*) 'electron-electron coll....'
call set_model('ee')
CASE ('ii')
IF( me .eq. 0) WRITE(*,*) 'ion-ion coll....'
call set_model('ii')
CASE DEFAULT
ERROR STOP('Coll_ab not defined')
END SELECT
!
! set model
SELECT CASE(coll_type)
CASE ('test')
IF( me .eq. 0) WRITE(*,*) 'Test component....'
CASE ('field')
IF( me .eq. 0) WRITE(*,*) 'Field component....'
CASE ('self')
IF( me .eq. 0) WRITE(*,*) 'Test + Field components....'
CASE DEFAULT
ERROR STOP('Coll_type not defined')
END SELECT
!
!
end subroutine model_readinputs
!================================================================================
subroutine set_model(ab)
! set the species mass/temperature ratios
implicit none
character(len=2), intent(in) :: ab
! Ion-Ion collisions
if(ab .eq. 'ii') then
chi_ = 1._dp
tau_ = 1._dp
sigma_ = 1._dp
end if
! Electron- Electron collisions
if(ab .eq. 'ee') then
chi_ = 1._dp
tau_ = 1._dp
sigma_ = 1._dp
end if
! Electron-ion collisions
if(ab .eq. 'ei') then
chi_ = SQRT(tauei/sigmaei)
tau_ = tauei
sigma_ = sigmaei
end if
! Ion-electron collisions
if(ab .eq. 'ie') then
chi_ = SQRT(tauie/sigmaie)
tau_ = tauie
sigma_ = sigmaie
end if
! set model parameter to FM type
CALL set_model_fm
!
end subroutine set_model
!================================================================================
subroutine set_model_fm
! set mass/temperature ratio to FM type
!
implicit none
!
CALL FM_ENTER_USER_ROUTINE
!
sigmafm_ = TO_FM(sigma_)
taufm_ = TO_FM(tau_)
chifm_ = SQRT(taufm_/sigmafm_)
!
!
CALL FM_EXIT_USER_ROUTINE
!
end subroutine set_model_fm
!================================================================================
end module model
c4science · Help